October 14, 2004
In this lesson you will develop a series of simple programs that
demonstrate the usage of ICY to compute a variety of different
geometric quantities applicable to experiments carried out by a remote
sensing instrument flown on an interplanetary spacecraft. This
particular lesson focuses on a framing camera flying on the Cassini
spacecraft, but many of the concepts are easily extended and
generalized to other scenarios.
The following SPICE tutorials are referred to by the discussions in
this lesson:
Name Lesson steps/routines it describes --------------- ----------------------------------------- Time Time Conversion SCLK and LSK Time Conversion SPK Obtaining Ephemeris Data Frames Reference Frames Using Frames Reference Frames PCK Planetary Constants Data CK Spacecraft Orientation DataThese tutorials are available from the NAIF ftp server at JPL:
ftp://naif.jpl.nasa.gov/pub/naif/toolkit_docs/Tutorials
The Required Reading documents are provided with the Toolkit and are
located under the ``icy/doc'' directory in the IDL installation tree.
Name Lesson steps/routines that it describes --------------- ----------------------------------------- time.req Time Conversion sclk.req SCLK Time Conversion spk.req Obtaining Ephemeris Data frames.req Using Reference Frames pck.req Obtaining Planetary Constants Data ck.req Obtaining Spacecraft Orientation Data naif_ids.req Determining Body ID Codes
Another useful document distributed with the Toolkit is the permuted
index. This is located under the ``icy/doc'' directory in the IDL
installation tree. This text document provides a simple mechanism to
discover what ICY functions perform a particular function of interest
as well as the name of the source module that contains the function.
The most detailed specification of a given ICY function is contained
in the header section of its source code. The source code is
distributed with the Toolkit and is located under ``icy/src/cspice''
in the IDL versions. For example the header of cspice_str2et is
contained in the file:
icy/src/cspice/str2et_c.c
The programs that are produced in the course of this lesson will
compute geometry for the Cassini orbiter. The following CASSINI SPICE
kernels will be used:
# FILE NAME TYPE DESCRIPTION -- ------------------------- ---- ------------------------ 1 naif0007.tls LSK Generic LSK 2 cas00084.tsc SCLK Cassini SCLK 3 sat128.bsp SPK Saturnian Satellite Ephemeris 4 981005_PLTEPH-DE405S.bsp SPK Solar System Ephemeris 5 020514_SE_SAT105.bsp SPK Saturnian Satellite Ephemeris 6 030201AP_SK_SM546_T45.bsp SPK Cassini Spacecraft SPK 7 cas_v37.tf FK Cassini FK 8 04135_04171pc_psiv2.bc CK Cassini Spacecraft CK 9 cpck05Mar2004.tpc PCK Cassini Project PCK 10 cas_iss_v09.ti IK ISS Instrument Kernel
This section provides a complete summary of the functions, and the
kernels that are suggested for usage in each of the exercises in this
tutorial. (You may wish to not look at this list unless/until you
``get stuck'' while working on your own.)
CHAPTER EXERCISE FUNCTIONS NON-VOID KERNELS
------- --------- ------------- --------- -------
1 convtm cspice_furnsh 1,2
cspice_prompt
cspice_str2et
cspice_etcal
cspice_timout
cspice_sce2c
cspice_sce2s
2 getsta cspice_furnsh cspice_vnorm 1,3-6
cspice_prompt
cspice_str2et
cspice_spkezr
cspice_spkpos
cspice_convrt
3 xform cspice_furnsh cspice_vsep 1-9
cspice_str2et
cspice_spkezr
cspice_sxform
cspice_mxvg
cspice_spkpos
cspice_pxform
cspice_mxv
cspice_convrt
4 subpts cspice_furnsh 1,3-6,9
cspice_str2et
cspice_subpt
cspice_subsol
5 fovint cspice_furnsh cspice_dpr 1-10
cspice_str2et
cspice_bodn2c
cspice_getfov
cspice_srfxpt
cspice_reclat
6 angles cspice_furnsh cspice_dpr 1-10
cspice_str2et
cspice_bodn2c
cspice_getfov
cspice_srfxpt
cspice_reclat
cspice_illum
Refer to the headers of the various functions listed above, as
detailed interface specifications are provided with the source code.
Write a program that prompts the user for an input UTC time string,
converts it to the following time systems and output formats:
Familiarity with the various time conversion and parsing functions
available in the Toolkit. Exposure to source code headers and their
usage in learning to call functions.
The solution to the problem can be broken down into a series of simple
steps:
When completing the ``calendar format'' step above, consider using one of two possible methods: cspice_etcal or cspice_timout.
The meta-kernel we created for the solution to this exercise is named
'convtm.mk'. Its contents follow:
KPL/MK
This is the meta-kernel used in the solution of the ``Time
Conversion'' task in the Remote Sensing Hands On Lesson.
\begindata
KERNELS_TO_LOAD = ( 'kernels/lsk/naif0007.tls',
'kernels/sclk/cas00084.tsc' )
\begintext
A sample solution to the problem follows:
PRO convtm
;;
;; Local Parameters
;;
METAKR = "convtm.mk"
SCLKID = -82
STRLEN = 50
utctim = ''
;;
;; Load the kernels his program requires.
;; Both the spacecraft clock kernel and a
;; leapseconds kernel should be listed in
;; the meta-kernel.
;;
cspice_furnsh, METAKR
;;
;; Prompt the user for the input time string.
;;
read, utctim, PROMPT="Input UTC Time: "
print, "Converting UTC Time: ", utctim
;;
;; Convert utctim to et.
;;
cspice_str2et, utctim, et
print, FORMAT="(A,F16.3)", " ET Seconds Past 2000: ", et
;;
;; Now convert ET to a formal calendar time
;; string. This can be accomplished in two
;; ways.
;;
cspice_etcal, et, calet
print, " Calendar ET (cspice_etcal): ", calet
;;
;; Or use cspice_timout for finer control over the
;; output format. The picture below was built
;; by examining the header of cspice_timout.
;;
cspice_timout, et , "YYYY-MON-DDTHR:MN:SC ::TDB", $
STRLEN, calet
print, " Calendar ET (cspice_timout): ", calet
;;
;; Convert ET to spacecraft clock time.
;;
cspice_sce2s, SCLKID, et, sclkst
print, " Spacecraft Clock Time: ", sclkst
cspice_unload, METAKR
END
After compiling the program, execute it:
Converting UTC Time: 2004 jun 11 19:32:00
ET Seconds Past 2000: 140254384.185
Calendar ET (cspice_etcal): 2004 JUN 11 19:33:04.184
Calendar ET (cspice_timout): 2004-JUN-11T19:33:04
Spacecraft Clock Time: 1/1465674964.105
Write a program that prompts the user for an input UTC time string,
computes the following quantities at that epoch:
Understand the anatomy of an cspice_spkezr call. Discover the
difference between cspice_spkezr and cspice_spkpos. Familiarity with
the Toolkit utility ``brief''. Exposure to unit conversion with ICY.
The solution to the problem can be broken down into a series of simple
steps:
When deciding which SPK files to load, the Toolkit utility ``brief'' may be of some use.
``brief'' is located in the ``icy/exe'' directory for IDL toolkits. Consult its user's guide available in ``icy/doc/brief.ug'' for details.
The meta-kernel we created for the solution to this exercise is named
'getsta.mk'. Its contents follow:
KPL/MK
This is the meta-kernel used in the solution of the
``Obtaining Target States and Positions'' task in the
Remote Sensing Hands On Lesson.
\begindata
KERNELS_TO_LOAD = ( 'kernels/lsk/naif0007.tls',
'kernels/spk/sat128.bsp'
'kernels/spk/981005_PLTEPH-DE405S.bsp',
'kernels/spk/020514_SE_SAT105.bsp',
'kernels/spk/030201AP_SK_SM546_T45.bsp' )
\begintext
A sample solution to the problem follows:
PRO getsta
;;
;; Local Parameters
;;
METAKR = "getsta.mk"
STRLEN = 50
utctim = ''
;;
;; Load the kernels that this program requires. We
;; will need a leapseconds kernel to convert input
;; UTC time strings into ET. We also will need the
;; necessary SPK files with coverage for the bodies
;; in which we are interested.
;;
cspice_furnsh, METAKR
;;
;; Prompt the user for the input time string.
;;
read, utctim, PROMPT = "Input UTC Time: "
print, "Converting UTC Time: ", utctim
;;
;; Convert utctim to et.
;;
cspice_str2et, utctim, et
print, FORMAT="(A,F16.3)", " ET Seconds Past 2000: ", et
;;
;; Compute the apparent state of Phoebe as seen from
;; CASSINI in the J2000 frame. All of the ephemeris
;; readers return states in units of kilometers and
;; kilometers per second.
;;
cspice_spkezr, "PHOEBE" , et , "J2000", "LT+S", $
"CASSINI", state, ltime
print, " Apparent State of Phoebe as seen " +$
"from CASSINI in the J2000 "
print, " frame (km, km/s): "
print, FORMAT="(A,F16.3)", " X = ", state[0]
print, FORMAT="(A,F16.3)", " Y = ", state[1]
print, FORMAT="(A,F16.3)", " Z = ", state[2]
print, FORMAT="(A,F16.3)", " VX = ", state[3]
print, FORMAT="(A,F16.3)", " VY = ", state[4]
print, FORMAT="(A,F16.3)", " VZ = ", state[5]
;;
;; Compute the apparent position of Earth as seen from
;; CASSINI in the J2000 frame. Note: We could have
;; continued using cspice_spkezr and simply ignored the
;; velocity components.
;;
cspice_spkpos, "EARTH" , et , "J2000", "LT+S", $
"CASSINI", pos, ltime
print, " Apparent position of Earth as " +$
"seen from CASSINI in the J2000 "
print, " frame (kilometers): "
print, FORMAT="(A,F16.3)", " X = ", pos[0]
print, FORMAT="(A,F16.3)", " Y = ", pos[1]
print, FORMAT="(A,F16.3)", " Z = ", pos[2]
;;
;; We need only display LT, as it is precisely the
;; light time in which we are interested.
;;
print, " One way light time between CASSINI and " +$
"the apparent position"
print, FORMAT="(A,F16.3)", " of Earth (seconds): ", $
ltime
;;
;; Compute the apparent position of the Sun as seen
;; from Phoebe in the J2000 frame.
;;
cspice_spkpos, "SUN" , et , "J2000", "LT+S", $
"PHOEBE", pos, ltime
print, " Apparent position of Sun as seen " +$
"from Phoebe in the "
print, " J2000 frame (kilometers): "
print, FORMAT="(A,F16.3)", " X = ", pos[0]
print, FORMAT="(A,F16.3)", " Y = ", pos[1]
print, FORMAT="(A,F16.3)", " Z = ", pos[2]
;;
;; Now we need to compute the actual distance between
;; the Sun and Phoebe. The above SPKPOS call gives us
;; the apparent distance, so we need to adjust our
;; aberration correction appropriately.
;;
cspice_spkpos, "SUN" , et , "J2000", "NONE", $
"PHOEBE", pos, ltime
;;
;; Compute the distance between the body centers in
;; kilometers.
;;
dist = cspice_vnorm ( pos )
;;
;; Convert this value to AU using cspice_convrt.
;; Recall, cspice_convrt cannot overwrite the
;; input with the output. Use 'dist_au' for the
;; output value.
;;
cspice_convrt, dist, "KM", "AU", dist_au
print, " Actual distance between Sun and Phoebe"
print, FORMAT="(A,F16.3)", " (AU): ", dist_au
cspice_unload, METAKR
END
After compiling the program, execute it:
Converting UTC Time: 2004 jun 11 19:32:00
ET Seconds Past 2000: 140254384.185
Apparent State of Phoebe as seen from CASSINI in the J2000
frame (km, km/s):
X = -119.921
Y = 2194.139
Z = -57.639
VX = -5.980
VY = -2.119
VZ = -0.295
Apparent position of Earth as seen from CASSINI in the J2000
frame (kilometers):
X = 353019393.123
Y = -1328180352.140
Z = -568134171.697
One way light time between CASSINI and the apparent position
of Earth (seconds): 4960.427
Apparent position of Sun as seen from Phoebe in the
J2000 frame (kilometers):
X = 376551465.272
Y = -1190495630.303
Z = -508438699.110
Actual distance between Sun and Phoebe
(AU): 9.012
Write a program that prompts the user for an input time string,
computes the following at the epoch of interest:
Familiarity with the different types of kernels involved in chaining
reference frames together, both inertial and non-inertial. Discover
some of the matrix and vector math functions. Understand the
difference between cspice_pxform and cspice_sxform.
The solution to the problem can be broken down into a series of simple
steps:
You may find it useful to consult the permuted index, the headers of various source modules, and the following toolkit documentation:
The meta-kernel we created for the solution to this exercise is named
'xform.mk'. Its contents follow:
KPL/MK
This is the meta-kernel used in the solution of the ``Spacecraft
Orientation and Reference Frames'' task in the Remote Sensing
Hands On Lesson.
\begindata
KERNELS_TO_LOAD = ( 'kernels/lsk/naif0007.tls',
'kernels/sclk/cas00084.tsc',
'kernels/spk/sat128.bsp'
'kernels/spk/981005_PLTEPH-DE405S.bsp',
'kernels/spk/020514_SE_SAT105.bsp',
'kernels/spk/030201AP_SK_SM546_T45.bsp',
'kernels/fk/cas_v37.tf',
'kernels/ck/04135_04171pc_psiv2.bc',
'kernels/pck/cpck05Mar2004.tpc' )
\begintext
A sample solution to the problem follows:
PRO xform
;;
;; Local Parameters
;;
METAKR = "xform.mk"
STRLEN = 50
utctim = ''
;;
;; Load the kernels that this program requires. We
;; will need:
;;
;; A leapseconds kernel
;; A spacecraft clock kernel for CASSINI
;; The necessary ephemerides
;; A planetary constants file (PCK)
;; A spacecraft orientation kernel for CASSINI (CK)
;; A frame kernel (TF)
;;
cspice_furnsh, METAKR
;;
;; Prompt the user for the input time string.
;;
read, utctim, PROMPT = "Input UTC Time: "
print, "Converting UTC Time: ", utctim
;;
;; Convert utctim to et.
;;
cspice_str2et, utctim, et
print, FORMAT="(A,F16.3)", " ET Seconds Past 2000: ", et
;;
;; Compute the apparent state of Phoebe as seen from
;; CASSINI in the J2000 frame. All of the ephemeris
;; readers return states in units of kilometers and
;; kilometers per second.
;;
cspice_spkezr, "PHOEBE" , et , "J2000", "LT+S", $
"CASSINI", state, ltime
;;
;; Now obtain the transformation from the inertial
;; J2000 frame to the non-inertial body-fixed IAU_PHOEBE
;; frame. Since we want the apparent position, we
;; need to subtract ltime from et.
;;
cspice_sxform, "J2000", "IAU_PHOEBE", et-ltime, sform
;;
;; Now rotate the apparent J2000 state into IAU_PHOEBE
;; with the following matrix multiplication:
;;
bfixst = transpose(sform) # state
;;
;; Display the results.
;;
print, " Apparent state of Phoebe as seen " +$
"from CASSINI in the IAU_PHOEBE"
print, " body-fixed frame (kilometers " +$
"and kilometers per second):"
print, FORMAT="(A,F19.6)", " X = ", bfixst[0]
print, FORMAT="(A,F19.6)", " Y = ", bfixst[1]
print, FORMAT="(A,F19.6)", " Z = ", bfixst[2]
print, FORMAT="(A,F19.6)", " VX = ", bfixst[3]
print, FORMAT="(A,F19.6)", " VY = ", bfixst[4]
print, FORMAT="(A,F19.6)", " VZ = ", bfixst[5]
;;
;; It is worth pointing out, all of the above could
;; have been done with a single use of cspice_spkezr:
;;
;;
cspice_spkezr, "PHOEBE" , et , "IAU_PHOEBE", "LT+S", $
"CASSINI", state, ltime
;;
;; Display the results.
;;
print, " Apparent state of Phoebe as seen " +$
"from CASSINI in the IAU_PHOEBE"
print, " body-fixed frame (kilometers " +$
"and kilometers per"
print, " second) obtained using " +$
"cspice_spkezr directly:"
print, FORMAT="(A,F19.6)", " X = ", state[0]
print, FORMAT="(A,F19.6)", " Y = ", state[1]
print, FORMAT="(A,F19.6)", " Z = ", state[2]
print, FORMAT="(A,F19.6)", " VX = ", state[3]
print, FORMAT="(A,F19.6)", " VY = ", state[4]
print, FORMAT="(A,F19.6)", " VZ = ", state[5]
;;
;; Now we are to compute the angular separation between
;; the apparent position of the Earth as seen from the
;; orbiter and the nominal boresight of the high gain
;; antenna. First, compute the apparent position of
;; the Earth as seen from CASSINI in the J2000 frame.
;;
cspice_spkpos, "EARTH" , et, "J2000", "LT+S", $
"CASSINI", pos, ltime
;;
;; Now compute the location of the antenna boresight
;; at this same epoch. From reading the frame kernel
;; we know that the antenna boresight is nominally the
;; +Z axis of the CASSINI_HGA frame defined there.
;;
bsight = [ 0.D0, 0.D0, 1.D0]
;;
;; Now compute the rotation matrix from CASSINI_HGA into
;; J2000.
;;
cspice_pxform, "CASSINI_HGA", "J2000", et, pform
;;
;; And multiply the result to obtain the nominal
;; antenna boresight in the J2000 reference frame.
;;
cspice_mxv, pform, bsight, bsight
;;
;; Lastly compute the angular separation.
;;
cspice_convrt, cspice_vsep(bsight, pos), "RADIANS", $
"DEGREES", sep
print, " Angular separation between the " +$
"apparent position of"
print, " Earth and the CASSINI high " +$
"gain antenna boresight (degrees):"
print, FORMAT="(A,F16.3)", " ", sep
;;
;; Or alternatively we can work in the antenna
;; frame directly.
;;
cspice_spkpos, "EARTH" , et , "CASSINI_HGA", "LT+S", $
"CASSINI", pos, ltime
;;
;; The antenna boresight is the Z-axis in the
;; CASSINI_HGA frame.
;;
bsight = [ 0.D0, 0.D0, 1.D0]
;;
;; Lastly compute the angular separation.
;;
cspice_convrt, cspice_vsep(bsight, pos), "RADIANS", $
"DEGREES", sep
print, " Angular separation between the " +$
"apparent position of"
print, " Earth and the CASSINI high " +$
"gain antenna boresight computed"
print, " using vectors in the CASSINI_HGA " +$
"frame (degrees):"
print, FORMAT="(A,F16.3)", " ", sep
cspice_unload, METAKR
END
After compiling the program, execute it:
Converting UTC Time: 2004 jun 11 19:32:00
ET Seconds Past 2000: 140254384.185
Apparent state of Phoebe as seen from CASSINI in the IAU_PHOEBE
body-fixed frame (kilometers and kilometers per second):
X = -1982.639762
Y = -934.530471
Z = -166.562595
VX = 3.970729
VY = -3.812531
VZ = -2.371665
Apparent state of Phoebe as seen from CASSINI in the IAU_PHOEBE
body-fixed frame (kilometers and kilometers per
second) obtained using cspice_spkezr directly:
X = -1982.639762
Y = -934.530471
Z = -166.562595
VX = 3.970729
VY = -3.812531
VZ = -2.371665
Angular separation between the apparent position of
Earth and the CASSINI high gain antenna boresight (degrees):
71.924
Angular separation between the apparent position of
Earth and the CASSINI high gain antenna boresight computed
using vectors in the CASSINI_HGA frame (degrees):
71.924
Write a program that prompts the user for an input UTC time string,
computes the following quantities at that epoch:
Discover higher level geometry calculation functions in ICY and their
usage as it relates to CASSINI.
This particular problem is more of an exercise in searching the
permuted index to find the appropriate functions and then reading
their headers to understand how to call them.
One point worth considering: Which method do you want to use to compute the sub-solar (or sub-observer) point?
The meta-kernel we created for the solution to this exercise is named
'subpts.mk'. Its contents follow:
KPL/MK
This is the meta-kernel used in the solution of the
``Computing Sub-spacecraft and Sub-solar Points'' task
in the Remote Sensing Hands On Lesson.
\begindata
KERNELS_TO_LOAD = ( 'kernels/lsk/naif0007.tls',
'kernels/spk/sat128.bsp'
'kernels/spk/981005_PLTEPH-DE405S.bsp',
'kernels/spk/020514_SE_SAT105.bsp',
'kernels/spk/030201AP_SK_SM546_T45.bsp',
'kernels/pck/cpck05Mar2004.tpc' )
\begintext
A sample solution to the problem follows:
PRO subpt
;;
;; Local Parameters
;;
METAKR = "subpts.mk"
STRLEN = 50
utctim = ''
;;
;; Load the kernels that this program requires. We
;; will need:
;;
;; A leapseconds kernel
;; The necessary ephemerides
;; A planetary constants file (PCK)
;;
cspice_furnsh, METAKR
;;
;; Prompt the user for the input time string.
;;
read, utctim, PROMPT = "Input UTC Time: "
print, "Converting UTC Time: ", utctim
;;
;; Convert utctim to et.
;;
cspice_str2et, utctim, et
print, FORMAT="(A,F16.3)", " ET Seconds Past 2000: ", et
;;
;; Compute the apparent sub-observer point of CASSINI
;; on Phoebe.
;;
cspice_subpt, "NEAR POINT", "PHOEBE", et, "LT+S", $
"CASSINI" , spoint , alt
print, " Apparent Sub-Observer point of CASSINI " +$
"on Phoebe in IAU_PHOEBE"
print, " (kilometers):"
print, FORMAT="(A,F16.3)", " X = ", spoint[0]
print, FORMAT="(A,F16.3)", " Y = ", spoint[1]
print, FORMAT="(A,F16.3)", " Z = ", spoint[2]
print, FORMAT="(A,F16.3)", " ALT = ", alt
;;
;; Compute the apparent sub-solar point on Phoebe
;; as seen from CASSINI.
;;
cspice_subsol, "NEAR POINT", "PHOEBE", et, "LT+S", $
"CASSINI" , spoint
print, " Apparent Sub-Solar point on Phoebe " +$
"as seen from CASSINI in IAU_PHOEBE"
print, " (kilometers):"
print, FORMAT="(A,F16.3)", " X = ", spoint[0]
print, FORMAT="(A,F16.3)", " Y = ", spoint[1]
print, FORMAT="(A,F16.3)", " Z = ", spoint[2]
END
After compiling the program, execute it:
Converting UTC Time: 2004 jun 11 19:32:00
ET Seconds Past 2000: 140254384.185
Apparent Sub-Observer point of CASSINI on Phoebe in IAU_PHOEBE
(kilometers):
X = 104.498
Y = 45.269
Z = 7.383
ALT = 2084.116
Apparent Sub-Solar point on Phoebe as seen from CASSINI in IAU_PHOEBE
(kilometers):
X = 78.681
Y = 76.879
Z = -21.885
Write a program that prompts the user for an input UTC time string and
computes the intersection of the CASSINI ISS NAC camera boresight with
the surface of Phoebe and presents it in the following coordinates:
Understand how field of view parameters are retrieved from instrument
kernels. Learn how various standard planetary constants are retrieved
from text PCKs. Discover how to compute the intersection of field of
view vectors with triaxial ellipsoidal target bodies.
This problem can be broken down into several simple, small steps:
The meta-kernel we created for the solution to this exercise is named
'fovint.mk'. Its contents follow:
KPL/MK
This is the meta-kernel used in the solution of the
``Intersecting Vectors with a Triaxial Ellipsoid'' task
in the Remote Sensing Hands On Lesson.
\begindata
KERNELS_TO_LOAD = ( 'kernels/lsk/naif0007.tls',
'kernels/sclk/cas00084.tsc',
'kernels/spk/sat128.bsp'
'kernels/spk/981005_PLTEPH-DE405S.bsp',
'kernels/spk/020514_SE_SAT105.bsp',
'kernels/spk/030201AP_SK_SM546_T45.bsp',
'kernels/fk/cas_v37.tf',
'kernels/ck/04135_04171pc_psiv2.bc',
'kernels/pck/cpck05Mar2004.tpc',
'kernels/ik/cas_iss_v09.ti' )
\begintext
A sample solution to the problem follows:
PRO fovint
;;
;; Local Parameters
;;
METAKR = "fovint.mk"
STRLEN = 50
BCVLEN = 4
utctim = ''
;;
;; Load the kernels that this program requires. We
;; will need:
;;
;; A leapseconds kernel.
;; A SCLK kernel for CASSINI.
;; Any necessary ephemerides.
;; The CASSINI frame kernel.
;; A CASSINI C-kernel.
;; A PCK file with Phoebe constants.
;; The CASSINI ISS I-kernel.
;;
cspice_furnsh, METAKR
;;
;; Prompt the user for the input time string.
;;
read, utctim, PROMPT = "Input UTC Time: "
print, "Converting UTC Time: ", utctim
;;
;; Convert utctim to et.
;;
cspice_str2et, utctim, et
print, FORMAT="(A,F16.3)", " ET Seconds Past 2000: ", et
;;
;; Now we need to obtain the FOV configuration of
;; the ISS NAC camera. To do this we will need the
;; ID code for CASSINI_ISS_NAC.
;;
cspice_bodn2c, "CASSINI_ISS_NAC", nacid, found
;;
;; Stop the program if the code was not found.
;;
if ( NOT found ) then begin
print, "Unable to locate the ID code for " +$
"CASSINI_ISS_NAC."
return
endif
;;
;; Now retrieve the field of view parameters.
;;
cspice_getfov, nacid, BCVLEN, shape, frame, bsight, $
bounds
;;
;; Call srfxpt to determine coordinates of the
;; intersection of this vector with the surface
;; of Phoebe.
;;
cspice_srfxpt, "Ellipsoid", "PHOEBE", et, "LT+S", $
"CASSINI", frame, bsight, point, $
dist, trgepc, obspos, found
;;
;; Check the found flag. Display a message if the
;; point of intersection was not found and stop.
;;
if ( NOT found ) then begin
print, "No intersection point found at this epoch."
return
endif
;;
;; Now, we have discovered a point of intersection.
;; Start by displaying the position vector in the
;; IAU_PHOEBE frame of the intersection.
;;
print, " Position vector of CASSINI NAC camera " +$
"boresight surface intercept"
print, " in the IAU_PHOEBE frame " +$
"(kilometers):"
print, FORMAT="(A,F16.3)", " X = ", point[0]
print, FORMAT="(A,F16.3)", " Y = ", point[1]
print, FORMAT="(A,F16.3)", " Z = ", point[2]
;;
;; Now express the coordinates of this point in
;; planetocentric latitude and longitude.
;;
cspice_reclat, point, radius, lon, lat
;;
;; Convert the angles to degrees for displaying.
;;
print, " Planetocentric coordinates of the " +$
"intercept (degrees):"
print, FORMAT="(A,F16.3)", " LAT = ", lat * cspice_dpr()
print, FORMAT="(A,F16.3)", " LON = ", lon * cspice_dpr()
END
After compiling the program, execute it:
Converting UTC Time: 2004 jun 11 19:32:00
ET Seconds Past 2000: 140254384.185
Position vector of CASSINI NAC camera boresight surface intercept
in the IAU_PHOEBE frame (kilometers):
X = 86.390
Y = 72.089
Z = 8.255
Planetocentric coordinates of the intercept (degrees):
LAT = 4.196
LON = 39.844
Write a program that prompts the user for an input time string and
computes the intersection of the CASSINI NAC camera boresight and
field of view boundary vectors with the surface of Phoebe. At these
points of intersection, if they exist, compute the following:
Display the results of the above computations if an intersection occurs, otherwise indicate the absence of an intersection. Use this program to compute values at the epoch "2004-01-12T4:15.24.000" UTC.
Discover another high level geometry function and another time
conversion function in ICY. Reinforce the concepts introduced in the
previous task.
Making use of the code you wrote for the previous task is probably the
fastest means to an end. A significant percentage of the task is
devoted to similar computations.
This problem can be broken down into several steps:
The meta-kernel we created for the solution to this exercise is named
'angles.mk'. Its contents follow:
KPL/MK
This is the meta-kernel used in the solution of the
``Computing Illumination Angles and Local Time'' task
in the Remote Sensing Hands On Lesson.
\begindata
KERNELS_TO_LOAD = ( 'kernels/lsk/naif0007.tls',
'kernels/sclk/cas00084.tsc',
'kernels/spk/sat128.bsp'
'kernels/spk/981005_PLTEPH-DE405S.bsp',
'kernels/spk/020514_SE_SAT105.bsp',
'kernels/spk/030201AP_SK_SM546_T45.bsp',
'kernels/fk/cas_v37.tf',
'kernels/ck/04135_04171pc_psiv2.bc',
'kernels/pck/cpck05Mar2004.tpc',
'kernels/ik/cas_iss_v09.ti' )
\begintext
A sample solution to the problem follows:
PRO angles
;;
;; Local Parameters
;;
METAKR = "angles.mk"
STRLEN = 50
BCVLEN = 5
utctim = ''
scan_vecs = dblarr( 3, BCVLEN )
vecnam = ["Boundary Corner 1", $
"Boundary Corner 2", $
"Boundary Corner 3", $
"Boundary Corner 4", $
"Boresight" ]
;;
;; Load the kernels that this program requires. We
;; will need:
;;
;; A leapseconds kernel.
;; A SCLK kernel for CASSINI.
;; Any necessary ephemerides.
;; The CASSINI frame kernel.
;; A CASSINI C-kernel.
;; A PCK file with Phoebe constants.
;; The CASSINI ISS I-kernel.
;;
cspice_furnsh, METAKR
;;
;; Prompt the user for the input time string.
;;
read, utctim, PROMPT = "Input UTC Time: "
print, "Converting UTC Time: ", utctim
;;
;; Convert utctim to et.
;;
cspice_str2et, utctim, et
print, FORMAT="(A,F16.3)", " ET Seconds Past 2000: ", et
;;
;; Now we need to obtain the FOV configuration of
;; the ISS NAC camera. To do this we will need the
;;ID code for CASSINI_ISS_NAC.
;;
cspice_bodn2c, "CASSINI_ISS_NAC", nacid, found
;;
;; Stop the program if the code was not found.
;;
if ( NOT found ) then begin
print, "Unable to locate the ID code for " +$
"CASSINI_ISS_NAC"
return
endif
;;
;; Now retrieve the field of view parameters.
;;
cspice_getfov, nacid, BCVLEN, shape, frame, bsight, bounds
;;
;; Rather than treat 'bsight' as a separate vector,
;; copy it and 'bounds to 'scan_vecs'.
;;
scan_vecs[ 0:11] = bounds[0:11]
scan_vecs[12:14] = bsight[0:2]
;;
;; Now perform the same set of calculations for each
;; vector listed in the 'bounds' array.
;;
for i=0, 4 do begin
;;
;; Call srfxpt to determine coordinates of the
;; intersection of this vector with the surface
;; of Phoebe.
;;
cspice_srfxpt, "Ellipsoid", "PHOEBE", et, "LT+S", $
"CASSINI", frame, scan_vecs[*,i], $
point, dist, trgepc, obspos, found
;;
;; Check the found flag. Display a message if
;; the point of intersection was not found,
;; otherwise continue with the calculations.
;;
print, "Vector: ", vecnam[i]
if ( NOT found ) then begin
print, "No intersection point found at " +$
"this epoch for this vector."
endif else begin
;;
;; Display the planetocentric latitude and longitude
;; of the intercept.
;;
cspice_reclat, point, radius, lon, lat
print, " Planetocentric coordinates of " +$
"the intercept (degrees):"
print, FORMAT="(A,F16.3)", " LAT = ", $
lat * cspice_dpr()
print, FORMAT="(A,F16.3)", " LON = ", $
lon * cspice_dpr()
;;
;; Compute the illumination angles at this
;; point.
;;
cspice_illum, "PHOEBE", et, "LT+S", "CASSINI", $
point, phase, solar, emissn
print, FORMAT="(A,F16.3)", $
" Phase angle (degrees): ", $
phase * cspice_dpr()
print, FORMAT="(A,F16.3)", $
" Solar incidence angle (degrees): ", $
solar * cspice_dpr()
print, FORMAT="(A,F16.3)", $
" Emission angle (degrees): ", $
emissn * cspice_dpr()
endelse
print
endfor
cspice_unload, METAKR
END
After compiling the program, execute it:
Converting UTC Time: 2004 jun 11 19:32:00
ET Seconds Past 2000: 140254384.185
Vector: Boundary Corner 1
Planetocentric coordinates of the intercept (degrees):
LAT = 1.028
LON = 36.433
Phase angle (degrees): 28.110
Solar incidence angle (degrees): 16.121
Emission angle (degrees): 14.627
Vector: Boundary Corner 2
Planetocentric coordinates of the intercept (degrees):
LAT = 7.492
LON = 36.556
Phase angle (degrees): 27.894
Solar incidence angle (degrees): 22.894
Emission angle (degrees): 14.988
Vector: Boundary Corner 3
Planetocentric coordinates of the intercept (degrees):
LAT = 7.373
LON = 43.430
Phase angle (degrees): 28.171
Solar incidence angle (degrees): 21.315
Emission angle (degrees): 21.977
Vector: Boundary Corner 4
Planetocentric coordinates of the intercept (degrees):
LAT = 0.865
LON = 43.239
Phase angle (degrees): 28.385
Solar incidence angle (degrees): 13.882
Emission angle (degrees): 21.763
Vector: Boresight
Planetocentric coordinates of the intercept (degrees):
LAT = 4.196
LON = 39.844
Phase angle (degrees): 28.140
Solar incidence angle (degrees): 18.247
Emission angle (degrees): 17.858